PchButik.se

Varuautomat

Arduino-kod

/* * 2015-08-15 * IDE version 1.6.5 * Sketch version 1.0.0 * pc_h * www.pchbutik.se * https://sites.google.com/site/pcharduino2015/myntinkast/varuautomat */


#include <SPI.h>

#include <Adafruit_GFX.h> //Detta bibliotek måste vara installerat, eller laddas ner och installeras.

#include <TFT_ILI9163C.h> //Detta bibliotek måste vara installerat, eller laddas ner och installeras.


//Pinnar till display

#define __CS 10

#define __DC 9


//Pinnar till varuautomat

#define _SOLENOID_1 A1

#define _SOLENOID_2 A2

#define _BUTTON_1_LED 5

#define _BUTTON_2_LED 7

#define _BUTTON_1_SWITCH 6

#define _BUTTON_2_SWITCH 8

#define _COIN_INSERTED 2

#define _COIN_INSERTED_RESERVED 3 // Reserv om det är två myntinkast.


#define _TIMER_SPEED 250 //Används för att skapa hastighet för blinkning och utmatning, 250 millisekunder är 4 per sekund


#define _COIN_VALUE 100 //Ett mynt är värt 100 öre alltså 1 krona


#define _COST_OF_PRODUCT_1 100 //Vara 1 kostar 100 öre alltså 10 kronor minst

#define _EJECTS_OF_PRODUCT_1 4 //Antal som ska matas ut av vara 1, så slutpriset är 0,25 Kr


#define _COST_OF_PRODUCT_2 300 //Vara 2 kostar 300 öre alltså 3 kronor minst

#define _EJECTS_OF_PRODUCT_2 1 //Antal som ska matas ut av vara 2, så slutpriset är 3 Kr


TFT_ILI9163C display = TFT_ILI9163C(__CS, __DC); //


volatile int EntererCoinInterrupt = 0; //Antalet inkastade mynt, Denna uppdateras av en interrupt för att inte missa något mynt

unsigned long EnterdCoinsValue = 0; //Värdet på instoppade pengar i öre

unsigned int Solonoid1Ejects = 0; //Hur många utmatningar som är kvar att göras av vara 1

unsigned int Solonoid2Ejects = 0; //Hur många utmatningar som är kvar att göras av vara 2


boolean Button1LedFlashing = false; //Om knapp för vara 1 ska binka eller inte

boolean Button2LedFlashing = false; //Om knapp för vara 2 ska binka eller inte


boolean Button1HasBeenUp = true;  //Om knapp 1 har varit släppt mellan två kontroller för tryck.

boolean Button2HasBeenUp = true;  //Om knapp 2 har varit släppt mellan två kontroller för tryck.


unsigned long LastLoopTime = 0; //Används för att skapa hastighet för blinkning och utmatning

unsigned long LoopSometimer = 0; //Används för att skapa hastighet för blinkning och utmatning


// the setup function runs once when you press reset or power the board

void setup() {
	// initialize digital output pins.

	pinMode(_SOLENOID_1, OUTPUT);
	pinMode(_SOLENOID_2, OUTPUT);
	pinMode(_BUTTON_1_LED, OUTPUT);
	pinMode(_BUTTON_2_LED, OUTPUT);

	//init output state

	digitalWrite(_SOLENOID_1, HIGH);
	digitalWrite(_SOLENOID_2, HIGH);
	digitalWrite(_BUTTON_1_LED, LOW);
	digitalWrite(_BUTTON_2_LED, LOW);

	// initialize digital input pins and med det inbyggda pullup motståndet aktivt.

	pinMode(_BUTTON_1_SWITCH, INPUT_PULLUP);
	pinMode(_BUTTON_2_SWITCH, INPUT_PULLUP);
	pinMode(_COIN_INSERTED, INPUT_PULLUP);

	//Testa display

	display.begin();
	display.setRotation(1);
	display.clearScreen();
	display.setCursor(0,0);
	display.print(F("pc_h - Tradera"));

	LastLoopTime = (millis() & 0xFFFF); //Används för att skapa hastighet för blinkning och utmatning


	UpdateUI();

	attachInterrupt(0, CoinInserted, FALLING); //Denna aktiverar interrupt nummer 0, som är på pinne 2

}

// the loop function runs over and over again forever

void loop() {
	//Används för att skapa hastighet för blinkning och utmatning

	long ThisLoopTime = (millis() & 0xFFFF);
	if(ThisLoopTime < LastLoopTime){
		//Rollover har skett

		LoopSometimer = LoopSometimer + (0xFFFF - LastLoopTime);
		LoopSometimer = LoopSometimer + ThisLoopTime;
	}else{
		LoopSometimer = LoopSometimer + (ThisLoopTime - LastLoopTime);
	}
	LastLoopTime = ThisLoopTime;
	if(LoopSometimer > _TIMER_SPEED){
		loopSometime();
		LoopSometimer = 0;
	}

	//Kontrollera knapp 1

	if( (digitalRead(_BUTTON_1_SWITCH) == LOW) && (Button1HasBeenUp == true) ){
		Button1HasBeenUp = false;
		if (EnterdCoinsValue >= _COST_OF_PRODUCT_1){ //Kolla att pengarna räcker till denna vara

			EnterdCoinsValue = EnterdCoinsValue - _COST_OF_PRODUCT_1; //Minska värdet på inlagda pengar med kostnaden av produkt 1

			Solonoid1Ejects = Solonoid1Ejects + _EJECTS_OF_PRODUCT_1; //Mata ut rätt antal av vara 1

			delay(200);
			UpdateUI();
		}
	}
	if(digitalRead(_BUTTON_1_SWITCH) == HIGH){
		Button1HasBeenUp = true;
	}

	//Kontrollera knapp 2

	if( (digitalRead(_BUTTON_2_SWITCH) == LOW) && (Button2HasBeenUp == true) ){
		Button2HasBeenUp = false;
		if (EnterdCoinsValue >= _COST_OF_PRODUCT_2){ //Kolla att pengarna räcker till denna vara

			EnterdCoinsValue = EnterdCoinsValue - _COST_OF_PRODUCT_2; //Minska värdet på inlagda pengar med kostnaden av produkt 2

			Solonoid2Ejects = Solonoid2Ejects + _EJECTS_OF_PRODUCT_2; //Mata ut rätt antal av vara 2

			delay(200);
			UpdateUI();
		}
	}
	if(digitalRead(_BUTTON_2_SWITCH) == HIGH){
		Button2HasBeenUp = true;
	}
}

void loopSometime() {
	//Denna anropas 4 gånger per sekund

	//Används för att skapa hastighet för blinkning och utmatning


	//Kolla om det kommit in mynt från interrupt

	if (EntererCoinInterrupt > 0){
		EnterdCoinsValue = EnterdCoinsValue + (EntererCoinInterrupt * _COIN_VALUE); //Räkna upp värdet för inkastade pengar.

		EntererCoinInterrupt = 0; //Nollställ mynt från interrupt

		UpdateUI(); //Uppdatera user interface, display och knappar som ska blinka

	}

	//Kolla om vara 1 ska matas ut och gör utmatning.

	if(digitalRead(_SOLENOID_1) == LOW){
		digitalWrite(_SOLENOID_1, HIGH);
	}else if  ( (digitalRead(_SOLENOID_1) == HIGH) && Solonoid1Ejects > 0 ){
		digitalWrite(_SOLENOID_1, LOW);
		Solonoid1Ejects --;
	}

	//Kolla om vara 2 ska matas ut och gör utmatning.

	if(digitalRead(_SOLENOID_2) == LOW){
		digitalWrite(_SOLENOID_2, HIGH);
	}else if  ( (digitalRead(_SOLENOID_2) == HIGH) && Solonoid2Ejects > 0 ){
		digitalWrite(_SOLENOID_2, LOW);
		Solonoid2Ejects --;
	}

	//Kolla om knapp för vara 1 ska blinka och gör blinkning

	if(Button1LedFlashing == true){
		if(digitalRead(_BUTTON_1_LED)){
			digitalWrite(_BUTTON_1_LED, LOW);
		}else{
			digitalWrite(_BUTTON_1_LED, HIGH);
		}
	}

	//Kolla om knapp för vara 2 ska blinka och gör blinkning

	if(Button2LedFlashing == true){
		if(digitalRead(_BUTTON_2_LED)){
			digitalWrite(_BUTTON_2_LED, LOW);
		}else{
			digitalWrite(_BUTTON_2_LED, HIGH);
		}
	}
}

void UpdateUI(){ //User Interface


	//Uppdatera display och visa inlagt värde

	display.clearScreen();
	display.setCursor(25,40);
	display.setTextSize(6);
	if(EnterdCoinsValue > 999){
		display.setCursor(20,40);
		display.setTextSize(5);
	}
	if(EnterdCoinsValue > 9999){
		display.setCursor(00,40);
		display.setTextSize(4);
	}
	display.print(EnterdCoinsValue/100);

	//Uppdatera blinkning och visa om kunden har råd med denna vara 1

	if (EnterdCoinsValue >= _COST_OF_PRODUCT_1) {
		Button1LedFlashing = true;
		digitalWrite(_BUTTON_1_LED, HIGH);
	}else{
		Button1LedFlashing = false;
		digitalWrite(_BUTTON_1_LED, LOW);
	}

	//Uppdatera blinkning och visa om kunden har råd med denna vara 2

	if (EnterdCoinsValue >= _COST_OF_PRODUCT_2) {
		Button2LedFlashing = true;
		digitalWrite(_BUTTON_2_LED, HIGH);
	}else{
		Button2LedFlashing = false;
		digitalWrite(_BUTTON_2_LED, LOW);
	}
}

//Interrupt Service Routine(ISR) to call when an interrupt occurs

//Efter som det bara kommer pulser från myntinkastet, så måste programmet vara med på noterna.

//När det kommer en puls på ingång 2, så avbryts allt program och denna anropas.

void CoinInserted(){

	//Denna for-loop gör inget annat än knycker 10mS, om det är en 16Mhz processor UNO-kort.

	for (int i=0; i<2700; i++){
		digitalRead(_COIN_INSERTED);
	}

	//Kolla att signalen fortfarande är låg efter 10mS

	if(digitalRead(_COIN_INSERTED) == LOW){
		EntererCoinInterrupt++;
	}
}